Ako majú lepkavé hlavičky pre GridLayout v Flickable

Je to trochu hacky, ale našiel som riešenie.

Najprv, vytvorte "fiktívne" hlavičky, ktoré sú Items. Môžete nastaviť, aby ich Layout.minimalWidth ak chcete byť šírka hlavičky text, ak potrebujete.

Potom, v Položke pred Flickable, vytvoriť hlavičku, uistite sa, že je horizontálne zarovnaný s mriežkou, a polohy prvkov pomocou x hodnoty hlavičky.

Nakoniec, zadajte zápornú marže na Flickable na odstránenie nadbytočných riadok pridaný figuríny hlavičky.

Tiež som sa snažil pomocou fillWidth: true na nechápavo a potom nastavenie width z každej hlavičke položky, ale nevýhodou je to, že upravuje tabuľka šírku stĺpca.

import QtQuick 2.0
import QtQuick.Layouts 1.12

ColumnLayout {
    width: 200
    height: 200

    // Header
    Item {
        Layout.minimumHeight: childrenRect.height
        Layout.fillWidth: true
        Text {
            id: header0
            x: headerDummy0.x
            anchors.top: parent.top
            text: "Header 0"
        }
        Text {
            id: header1
            x: headerDummy1.x
            anchors.top: parent.top
            text: "Header 1"
        }
        Text {
            id: header2
            x: headerDummy2.x
            anchors.top: parent.top
            text: "Header 2"
        }
    }

    Flickable {
        Layout.fillWidth: true
        Layout.preferredHeight: 200
        contentWidth: width
        contentHeight: grid.height
        clip: true
        // Eliminate the first row, which are the dummies
        topMargin: - grid.rowSpacing

        GridLayout {
            id: grid
            columns: 3
            rowSpacing: 50
            columnSpacing: 10

            function reparentChildren(source, target) {
                while (source.children.length) {
                    source.children[0].parent = target;
                }
            }

            // Header dummies
            Item {
                id: headerDummy0
                Layout.minimumWidth: header0.implicitWidth
            }
            Item {
                id: headerDummy1
                Layout.minimumWidth: header1.implicitWidth
            }
            Item {
                id: headerDummy2
                Layout.minimumWidth: header2.implicitWidth
            }

            // Data
            Repeater {
                model: 50

                Item {
                    Component.onCompleted: grid.reparentChildren(this, grid)
                    Text {
                        text: "Column 0, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 1, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 2, %1".arg(modelData)
                    }
                }
            }
        }
    }
}